Landau-Niveaus

(früher schrieb man Landau-Niveaux heute vielleicht Landau-Nivos)

Das Elektron im homogenen B-Feld zeigt erstaunliche Eigenschaften - jedenfalls quantenmechanisch. Wenn man sie ernst nimmt, bekommt man dafür den Nobelpreis (ganz oder gebrochen)!

Wir beginnen mit den einfachen Übungen, den 'Landau-Niveaus':

Landau-Lifschitz III, S. 443

Die Wellenfunktion für einen Elektronenzustand im homogenen B-Feld ist die Wellenfunktion des harmonischen Oszillators (endlich einmal eine sinnvolle Anwendung des harmonischen Oszillators in der Quantenphysik :-):

> chi:=(n,xi)->1/sqrt(ah*2^n*n!)*exp(-(xi^2/2))*H(n,xi);

Die Hermiteschen Polynome gibt es im Package 'orthopoly'

> with(orthopoly):

Zum Beispiel

> H(17,x);

Oder

> chi(10,xi);

Dabei ist

> ah:=sqrt(hq/(m*omega));

und die Zyklotronfrequenz

> omega:=e*B/(m*c);

Also

> chi(n,z);

mit der Variablen

> xi:=(y-y0)/ah;

sowie

> y0:=-c*px/(e*B);

Also

> chi(n,xi);

Die Masse fällt demnach heraus und wir nehmen für die Naturkonstanten jeweils 1:

> hq,e,c:=1,1,1;

> chi(n,xi);

Tests:

> px:=1:B:=1:

> chi(3,xi);

> plot(chi(3,xi),y=-5..5);

Wahrschinlichkeitsdichten:

> B:=1:

> plot([seq(chi(n,xi)^2,n=0..3)],y=-8..8);

Die Bedeutung von px und y0 muß noch interpretiert werden. Wir wählen vorläufig px (den Impuls in x-Richtung) gleich Null und ändern versuchsweise das B-Feld etwas.

> B:=0.5:px:=0:

> plot([seq((y-y0)^2*chi(n,xi)^2,n=0..3)],y=-8..8);

Man kann auch die Maxima von bestimmen:

> solve(diff(chi(3,xi)^2,y));

Wie müssen wir normieren?

> px:=10:B:=4:

> int(chi(5,xi)^2,y=-infinity..infinity);

Das ist unabhänig von B und px, jedenfalls liefert Maple hier 'für alle' Einsetzungen von B und px .

Wie ändert sich die Lage der Maxima mit B?

> px:=0:B:='B':

> plot3d(chi(3,xi)^2,y=-4..4,B=0.001..2,axes=framed,grid=[50,50],orientation=[-115,50]);

Eine andere Art der Darstellung:

> plot3d(chi(3,xi)^2,y=-4..4,B=0.001..2,axes=framed,grid=[50,50]);

Dabei gilt für den feldfreien Fall:

> limit(chi(3,xi)^2,B=0);

Klassischer Radius aus Energie:

> B:='B':m:='m':omega;

> n:='n':E:=(n+1/2)*hq*omega;

> rq:=simplify(sqrt(2*E/m)/omega);

Das ist abhängig von m! Aber wir vereinfachen:

> m:=1:rq;

Zum Vergleich die klassische Aufenthaltswahrscheinlichkeit awals Kehrwert der Geschwindigkeit, berechnet aus der kinetischen Energie des harmonischen Oszillators.

> aw:=1/sqrt(rq^2-y^2)/Pi;

Die Normierung erhält man z.B. so:

> r0:='r0':int(1/sqrt(r0^2-y^2),y=-r0..r0);

> r0:=2:

> int(1/sqrt(r0^2-y^2),y=-r0..r0);

und das ist unabhängig von r0 (wie man durch Einsetzen von verschiedenen Werten für r0 leicht beweisen kann :-).

Darstellung der quantenmechanischen Verteilung und Vergleich mit den klassischen Größen aw und rq(χ) ist jetzt korrekt mit normiert.

> px:=0:B:=1:n:=40:evalf(rq);

> display(plot(chi(n,xi)^2/sqrt(Pi),y=-1.2*rq..1.2*rq,numpoints=500),plot([[rq,0],[rq,1]],color=blue),plot([[-rq,0],[-rq,1]],color=blue),plot(aw,y=-0.99*rq..0.99*rq,color=black),view=[-1.2*rq..1.2*rq,0..1]);

Man erahnt den Übergang von der Quantenphysik zur klassischen Physik, aber vielleicht kann man ihn so leichter nachvollziehen:

> n:='n':

> display([seq(display(plot(chi(n,xi)^2/sqrt(Pi),y=-1.2*rq..1.2*rq,numpoints=500),plot([[rq,0],[rq,1]],color=blue),plot([[-rq,0],[-rq,1]],color=blue),plot(aw,y=-0.99*rq..0.99*rq,color=black),view=[-1.2*rq..1.2*rq,0..1]),n=0..40)],insequence=true);

Tja - auch für n = 40 scheint da noch ein 'kleiner Rest des Elektrons' innerhalb der Kreisbahn zu bleiben.

Wie soll man sich das Landau-Elektorn überhaupt räumlich vorstellen? Einfach rotationssymmetrisch?

> n:=10:r:='r':

> plot3d([y*cos(theta),y*sin(theta),chi(n,xi)^2],y=0..1.5*rq,theta=0..2*Pi,axes=framed,grid=[30,40]);

Das wäre ziemlich klassisch gedacht. Quantenmechanisch sieht es eher so aus,

> plot3d([x,y,chi(n,xi)^2],y=-1.5*rq..1.5*rq,x=0..2,axes=framed,grid=[100,2]);

weil mit Vorgabe des Impulses in x-Richtung (hier ) der Ort des Kreismittelpunktes in x-Richtung unbestimmt wird.

Und wie sieht - nebenbei gefragt - eigentlich der Term der Wellenfunktion für große n aus?

> sort(chi(60,xi));

Das ist Computer-Algebra! Etwas kompakter...

> sort(evalf(chi(60,xi)));

Nach so viel Computeralgebra sollten wir noch ein paar einfache Rechnungen anstellen.

Welche Quantenzahlen gehören denn zu einem 'makroskopischen Landau-Zustand'?

Zur Beantwortung dieser Frage benötigen wir zunächst die Naturkonstanten.

> restart:

> hq:=evalf(4.136/2/Pi*10^(-15)); # eVs

> e:=1.6*10^(-19); # C

> m:=9.1*10^(-31); # kg

Eine Gleichung für die Quantenzahl (die Nullpunktsenergie vernachlässigen wir großzügig):

> n:=E/(hq*omega); # E in eV

Die Zyklotronfrequenz

> omega:=e/m*B; # B in Tesla

Und als zusätzliche Information den Radius der Bahn

> r:=sqrt(2*E/(omega*B));

Wir nehmen ein Zahlenbeispiel (B in Tesla, E in eV):

> B:=0.01:E:=1000:'B'=B*Tesla;'E'=E*eV;'omega'=omega*Hz; 'r'=evalf(r)*'m';'n'=round(n);

Auf Deutsch: Zu einer makroskopischen Bewegung mit einem Radius von 1cm gehört eine Quantenzahl von Achthundertvierundsechzigmillionenunddreizehntausendneunhundertsiebenunddreißig.

Und die klassische Antreffwahrscheinlichkeit sieht so aus:

> aw:=1/sqrt(r^2-y^2)/Pi;

> plot(aw,y=-r..r);

Leider konnte ich bis heute Maple nicht dazu bewegen, in endlicher Zeit zu zeichnen. Es sollte aber ganz ähnlich aussehen.

Siehe auch: Schrödingers Oszillator

Moderne Physik mit Maple

komma@oe.uni-tuebingen.de