Vorbemerkungen

Abi-Aufgaben werden in ein paar Jahren sicher mit dem Computer bearbeitet (nicht nur in Mathematik). Ausgehend von dieser Tatsache müssen heute schon Aufgabenstellungen konzipiert werden, die möglichst weit vorausblickend angelegt sind. Nach der Pilotphase sollten wir deshalb bald zu einer konsensfähigen breiten Basis kommen. Dazu benötigen wir das ganze Meinungsspektrum und die Beteiligung aller. In diesem Sinne:

1. Bei der folgenden Abi-Aufgabe handelt es sich um eine Skizze, mit der auch die Problematik der Aufgabenstellung und der Bewertung der Lösungen von zukünftigen Abi-Aufgaben aufgezeigt werden soll.

2. Vom Schüler wird bei dieser 'Geometrie-Aufgabe' keinerlei Rechenfertigkeit verlangt.

3. Der Schüler hat bei der Klausur alle benötigten Befehle (und Fallbeispiele dazu) auf seinem Computer 'zur Hand', ggf. in selbst erstellten Menüs, Paletten oder Bibliotheken.

4. Der Hauptakzent der Aufgabenstellung liegt auf dem 'Lösen eines Problems', d.h., der richtig ausgebildete Schüler sollte sein CAS (und Papier und Bleistift) dazu einsetzen, sich in der Aufgabe zurechtzufinden (Heuristik) und dann selbständig - wie in einem Erörterungsaufsatz - neuen (selbst gefundenen) Fragestellungen konsequent nachzugehen.

5. Die Bearbeitungszeit beträgt mindestens 3 Zeitstunden. (Von dem Prüfling würde man einen ausführlicheren Begleittext erwarten als vom Aufgabensteller. Warum müssen Prüfungen übrigens zeitlich beschränkt durchgeführt werden?)

6. Verschiedene Stellen der Aufgabenstellung und der angebotenen Lösung müssen noch für Nicht-Physiker übersetzt (entgratet) werden. Für entsprechende Kommentare wäre ich dankbar: komma@oe.uni-tuebingen.de.

7. Um eine Diskussion über solche Aufgabenstellungen möglichst offen zu halten, habe ich es vermieden, Teilaufgaben oder Anleitungen zu formulieren. Es gibt nur eine offene Frage:

Die Aufgabe

Abitur 1999

Angewandte Geometrie

Es soll der Stoß zweier Kugeln (Kreisscheiben) untersucht werden. Dabei soll gelten:

- Beide Kugeln sind gleich groß.

- Die Kugel 1 nähert sich der ruhenden Kugel 2 auf geradliniger Bahn mit der Geschwindigkeit [Maple Math] . Der Abstand dieser Bahn vom Zentrum der Kugel 2 heiße Stoßparameter b .

- Beim Stoß kann zwischen den Kugeln nur Kraft in Richtung der Stoßnormalen (das ist die Verbindungslinie der Kugelzentren) übertragen werden. Die Tangentialkomponente der Geschwindigkeit der ankommenden Kugel 1 ändert sich nicht.

- Für die Geschwindigkeitskomponenten in Richtung der Stoßnormalen gilt nach dem Stoß:

[Maple Math] ' = [Maple Math]

und [Maple Math] ' = [Maple Math]

- Nach dem Stoß bewegen sich die Kugeln geradlinig und mit konstanten Geschwindigkeiten.

Heuristik

> restart:

> with(geometry):_EnvHorizontalName := 'x': _EnvVerticalName := 'y':

Der erste Schritt der Behandlung des Problems besteht in der Wahl eines geeigneten Koordinatensystems. Weil über den Radius der Kugeln keine Zahlenangaben vorliegen, kann er z.B. gleich 1 gewählt werden. Es genügt, das Problem zweidimensional zu behandeln.

Ruhende Kugel:

> circle(k2,[point(O,[0,0]),1]);

[Maple Math]

> detail(k2);

name of the object: k2

form of the object: circle2d

name of the center: O

coordinates of the center: [0, 0]

radius of the circle: 1

equation of the circle: x^2-1+y^2 = 0

>

Eine 'Skizze' kann nichts schaden:

> draw(k2);

Die 'Kugel' 2 ist also bekannt.

Stoßparameter und Bahn der ankommenden Kugel

>

> point(A,0,b),point(B,1,b):

> line(l,[A,B]);

[Maple Math]

Das war die Elementaraufgabe 'Gerade durch zwei Punkte'.

Eine Skizze zum Test:

> b:=7/4:

> draw({l,k2},view=[-5..5,-5..5],axes=normal,scaling=constrained);

[Maple Plot]

Die ankommende Kugel sollte ihr Zentrum auf obiger Geraden haben:

>

> circle(k1,[point(P,x1,b),1]);

[Maple Math]

> detail(k1);

name of the object: k1

form of the object: circle2d

name of the center: P

coordinates of the center: [x1, 7/4]

radius of the circle: 1

equation of the circle: x^2+33/16+y^2-2*x1*x-7/2*y+x1^2 = 0

Ein Versuch:

> x1:=-2:detail(k1);

name of the object: k1

form of the object: circle2d

name of the center: P

coordinates of the center: [-2, 7/4]

radius of the circle: 1

equation of the circle: x^2+97/16+y^2+4*x-7/2*y = 0

Wir kennen auch die Gleichung von k1, falls wir sie benötigen...

>

Noch eine Skizze:

> draw({l,k1,k2},view=[-5..5,-5..5],axes=normal,scaling=constrained);

[Maple Plot]

Nun sollten wir [Maple Math] so bestimmen, daß die Kugeln sich berühren.

Das geht mit einem Hilfskreis, der uns auch die Stoßnormale liefert:

> circle(kh,[O,2],[x,y]);

[Maple Math]

>

> draw({l,k2,kh},view=[-5..5,-5..5],axes=normal,scaling=constrained);

[Maple Plot]

Wo schneidet der Hilfskreis die Bahn der ankommen Kugel (genau!)?

> intersection(inter,l,kh,[Q1,Q2]);

[Maple Math]

> detail(inter);

name of the object: Q1

form of the object: point2d

coordinates of the point: [1/4*15^(1/2), 7/4]

name of the object: Q2

form of the object: point2d

coordinates of the point: [-1/4*15^(1/2), 7/4]

> coordinates(Q2);

[Maple Math]

>

Also haben wir als Stoßnormale:

> line(l3,[O,Q2]);

[Maple Math]

> x1:=coordinates(Q2)[1];

[Maple Math]

Stimmt das?

> draw({l,k1,kh,l3,k2},view=[-5..5,-5..5],axes=normal,scaling=constrained);

[Maple Plot]

In welche Richtung sich die Kugel 2 nach dem Stoß bewegt, wissen wir nun also.

Und in welchem Punkt berühren sich die Kugeln?

> intersection(inter2,k1,k2);

[Maple Math]

> detail(inter2);

name of the object: inter2

form of the object: point2d

coordinates of the point: [-1/8*15^(1/2), 7/8]

Oder:

> intersection(inter1,k2,l3,[R,S]);

[Maple Math]

> detail(inter1);

name of the object: R

form of the object: point2d

coordinates of the point: [-1/8*15^(1/2), 7/8]

name of the object: S

form of the object: point2d

coordinates of the point: [1/8*15^(1/2), -7/8]

>

>

Für die Bewegung der Kugel 1 nach dem Stoß benötigen wir die gemeinsame Tangente der Kugeln:

> PerpendicularLine(lp, R, l3);

[Maple Math]

> detail(lp);

name of the object: lp

form of the object: line2d

equation of the line: -2-1/4*15^(1/2)*x+7/4*y = 0

>

Kontrollskizze:

> draw([lp,l,k1,kh,l3,k2],view=[-5..5,-5..5],axes=normal,scaling=constrained);

[Maple Plot]

Für später kann es nicht schaden, wenn wir uns einen Plot dieser Situation aufbewahren:

> pl1:=draw([lp,l,k1,l3,k2],view=[-5..5,-5..5],axes=normal,scaling=constrained):pl1;

[Maple Plot]

>

Falls uns jemand nach Winkeln fragen würde, könnten wir ihn so zufriedenstellen:

> evalf(FindAngle(l, lp)*180/Pi);

[Maple Math]

> evalf(FindAngle(l, l3)*180/Pi);

[Maple Math]

>

Nun sollten wir uns mit den Geschwindigkeitsvektoren beschäftigen. Weil in der Aufgabe nichts über den Betrag von [Maple Math] ausgesagt ist, können wir ihn z.B. gleich 5 wählen (Anmerkung: In Release 5 kann für den Pfeil ein Richtungsvektor (vector()) eingegeben werden. In Release 4 bitte vector() löschen):

> v:=plottools[arrow](coordinates(P), vector([5,0]), .2, .4, .1, color=green):
plots[display](v,pl1);

[Maple Plot]

>

Wir suchen nun die Projektion dieses Vektors auf die Stoßnormale und die Tangente. Das geht z.B. mit dem Endpunkt des oben eingezeichneten Geschwindigkeitsvektors:

> point(VP,coordinates(P)[1]+5,coordinates(P)[2]);

[Maple Math]

Und dem passenden Maple-Befehl.

Bestimmung der Normalkomponente der Geschwindigkeit:

> projection(VNP,VP,l3);

[Maple Math]

> coordinates(VNP);

[Maple Math]

Sieht das auch vernünftig aus?

> draw({l3,lp,l,VNP},axes=normal);

[Maple Plot]

Könnte schon sein...

> VN:=coordinates(VNP)-coordinates(P);

[Maple Math]

>

> vn:=plottools[arrow](coordinates(P), vector(VN), .2, .4, .1, color=red):

>

> plots[display](v,pl1,vn);

[Maple Plot]

Ja - das sieht vernünftig aus!

Dann können wir uns ja der Bahn der Kugel 1 nach dem Stoß und der Tangentialkomponente der Geschwindigkeit zuwenden und gleich noch ein paar Hilfslinien einzeichnen:

> ParallelLine(lt, P, lp );

[Maple Math]

>

> plots[display](v,pl1,vn,draw(lt));

[Maple Plot]

>

> projection(VNT,VP,lt);

[Maple Math]

>

Tangentiale Geschwindigkeitskomponente

> VT:=vector(coordinates(VNT)-coordinates(P));

[Maple Math]

>

> coordinates(VNT)-coordinates(P);

[Maple Math]

>

>

Geschwindigkeitskomponenten (Zeichnung)

> vt:=plottools[arrow](coordinates(P), VT, .2, .4, .1, color=blue):

>

> plots[display](v,pl1,vn,vt);

[Maple Plot]

>

> plots[display](v,pl1,vn,vt,draw(ParallelLine(lh, VP, l3 )),draw(ParallelLine(lh2, VP, lp )));

[Maple Plot]

>

>

Falls uns jemand nach dem Betrag der Geschwindigkeitskomponenten fragen würde:

> vtabs:=linalg[norm](VT);

[Maple Math]

> vnabs:=linalg[norm](VN);

[Maple Math]

>

>

Und wie wäre es mit einer Animation?

Kugel 1 vor dem Stoß:

> circle(k1t,[point(T,[5*t+coordinates(P)[1],coordinates(P)[2]]),1]);

[Maple Math]

>

>

> plots[display]([seq(draw({k1t,k2},axes=normal),t=-4..4)], scaling=constrained);

[Maple Plot]

Im Prinzip läuft das also - wenn man Maple hat und die option 'insequence=true' hinzufügt. Aber die Kugel 1 läuft noch durch die Kugel 2 durch, ohne sie zu stoßen.

>

Wir müssen die Bewegung in zwei Abschnitte unterteilen. Aber welche Geschwindigkeiten nehmen wir für die Kugeln nach dem Stoß?

Die Formeln in der Aufgabenstellung erscheinen besonders einfach für [Maple Math]

Dann wird nämlich die Normalkomponente der Geschwindigkeit der Kugel 1 nach dem Stoß Null und die Kugel 2 übernimmt gerade diese Geschwindigkeit.

Kugel 1:

> circle(k1s,[point(TS,[VT[1]*t+coordinates(P)[1],VT[2]*t+coordinates(P)[2]]),1]);

[Maple Math]

> plots[display]([seq(draw({k1t,k2},axes=normal),t=-4..0)],[seq(draw({k1s,k2},axes=normal),t=1..4)],scaling=constrained);

[Maple Plot]

>

Kugel 2 nach dem Stoß

> circle(k2s,[point(T2S,[VN[1]*t,VN[2]*t]),1]);

[Maple Math]

> plots[display]([seq(draw([k1t,k2,l],color=[blue,red],axes=normal,printtext=false,filled=true),t=seq(0.5*i,i=-4..0))],[seq(draw([k1s,k2s,lp,l3],color=[blue,red],axes=normal,printtext=false,filled=true),t=seq(0.5*j,j=1..10))],scaling=constrained);

[Maple Plot]

>

Wie gesagt: Wer sich die Lösung dieser Abi-Aufgabe nicht nur mit einem Browser ansehen kann, sondern mit Maple arbeiten kann, der fügt 'insequence=true' hinzu und sieht die Kugeln laufen.... und kann eigene Hilfsgeraden einzeichnen...

>

>

>

Ungleiche Massen und variabler Stoßparameter

Wir haben oben angenommen, daß die Massen der Kugeln gleich groß sind, und das Problem nur für einen bestimmten Stoßparameter untersucht. Das ist natürlich nicht im Sinne einer allgemeinen Untersuchung des Problems. Aber wir können den größten Teil unserer Heuristik mit Copy&Paste übernehmen und an den entscheidenden Stellen verändern.

(Kugel 2 ruht weiterhin vor dem Stoß. Der Stoß ist weiterhin voll elastisch und die Kugeln sind weiterhin gleich groß... nur um ein paar weitere Variationsmöglichkeiten der Aufgabenstellung anzudeuten)

> restart:
Stoßparameter eingeben:
b:=1/4:

Zu 'restart' zurückkehren, wenn ein anderer Stoßparameter eingegeben werden soll. (Dies ist die für den Stoßparameter entscheidende Stelle).

>

> with(geometry):_EnvHorizontalName := 'x': _EnvVerticalName := 'y':

Ruhende Kugel

> circle(k2,[point(O,[0,0]),1]):

Stoßparameter und Bahn der ankommenden Kugel

> point(A,0,b),point(B,1,b):

> line(l,[A,B]):

Ankommende Kugel

> circle(k1,[point(P,x1,b),1]):

Hilfskreis zur Bestimmung der Stoßnormalen

> circle(kh,[O,2],[x,y]):

> intersection(inter,l,kh,[Q1,Q2]):

Stoßnormale

> line(l3,[O,Q2]):

> x1:=coordinates(Q2)[1]:

Stoßpunkt

> intersection(inter2,k1,k2):

> intersection(inter1,k2,l3,[R,S]):

Tangente

> PerpendicularLine(lp, R, l3):

Geschwindigkeitsvektor

point(VP,coordinates(P)[1]+5,coordinates(P)[2]):

Bestimmung der Normalkomponente der Geschwindigkeit

> projection(VNP,VP,l3):

> VN:=coordinates(VNP)-coordinates(P):

Bahn der Kugel 1 nach dem Stoß

> ParallelLine(lt, P, lp ):

> projection(VNT,VP,lt):

Tangentiale Geschwindigkeit

> VT:=vector(coordinates(VNT)-coordinates(P)):

Kugel 1 vor dem Stoß

> circle(k1t,[point(T,[5*t+coordinates(P)[1],coordinates(P)[2]]),1]):

Kugel 1 nach dem Stoß

> circle(k1s,[point(TS,[VT[1]*t+coordinates(P)[1],VT[2]*t+coordinates(P)[2]]),1]):

Kugel 2 nach dem Stoß

> circle(k2s,[point(T2S,[VN[1]*t,VN[2]*t]),1]):

> m1:='m1':m2:='m2':

Nun berücksichtigen wir ungleiche Massen
(die zweite entscheidende Stelle für die Verallgemeinerung):

> M:=m1+m2:

> V1S:=[VT[1]+(m1-m2)/M*VN[1],VT[2]+(m1-m2)/M*VN[2]]:

> V2S:=[(2*m1)/M*VN[1],2*m1/M*VN[2]]:

> Kugel 1 nach dem Stoß

> circle(k1sm,[point(TSM,[V1S[1]*t+coordinates(P)[1],V1S[2]*t+coordinates(P)[2]]),1]):

Kugel 2 nach dem Stoß

> m1:='m1':m2:='m2':

> circle(k2sm,[point(T2SM,[V2S[1]*t,V2S[2]*t]),1]):

Eingabe der Massen:

> m1:=1:m2:=4:

> plots[display]([seq(draw([k1t,k2,l],color=[blue,red],axes=normal,printtext=false,filled=true),t=seq(0.5*i,i=-2..0))],[seq(draw([k1sm,k2sm,lp,l3],color=[blue,red],axes=normal,printtext=false,filled=true),t=seq(0.5*j,j=1..6))],scaling=constrained);

[Maple Plot]

>

Neuer Stoßparameter

Neue Massen

>

Weitere Verallgemeinerungen

Natürlich ist es nicht verboten, ein Blatt Papier zu Hilfe zu nehmen. Man findet so mit elementargeometrischen Überlegungen eine Darstellung, die sich besser verallgemeinern läßt.

> restart:
with(linalg):

> with(geometry):

Warning, new definition for norm

Warning, new definition for trace

>

Geschwindigkeitsvektor der Kugel 1:

> V1:=[v1,0];

[Maple Math]

Einheitsvektoren in Richtung der gemeinsamen Tangente und der Stoßnormalen:

> ET:=[ca,sa];

> EN:=[sa,-ca];

[Maple Math]

[Maple Math]

>

Geschwindigkeitskomponenten:

> vt:=dotprod(V1,ET,'orthogonal');

[Maple Math]

> VT:=evalm(vt*ET);

[Maple Math]

>

> vn:=dotprod(V1,EN,'orthogonal');

[Maple Math]

> VN:=evalm(vn*EN);

[Maple Math]

>

>

Sinus und Cosinus

> sa:=sqrt(1-ca^2);

> ca:=b/2;

[Maple Math]

[Maple Math]

>

Die Geschwindigkeitsvektoren nach dem Stoß:

> V1S:=evalm(VT+(m1-m2)/(m1+m2)*VN);

[Maple Math]

> V2S:=evalm(2*m1/(m1+m2)*VN);

[Maple Math]

Kontrollausgaben:

> b:='b':

> print(V2S);

[Maple Math]

> V2S[2];

[Maple Math]

>

>

>

>

Die ruhende Kugel 2:

> circle(k2,[point(O,[0,0]),1]):

> _EnvHorizontalName := 'x': _EnvVerticalName := 'y':
Stoßparameter und Bahn der ankommenden Kugel

>

Die Bahn der ankommenden Kugel 1:

> point(A,0,b),point(B,1,b):

> line(l,[A,B]):

Der Berührungspunkt:

> point(P,-2*sa,b);

[Maple Math]

> detail(P);

name of the object: P

form of the object: point2d

coordinates of the point: [-2*(1-1/4*b^2)^(1/2), b]

>

Kugel 1 vor dem Stoß

> circle(k1t,[point(T,[v1*t+coordinates(P)[1],coordinates(P)[2]]),1]):

> detail(k1t);

name of the object: k1t

form of the object: circle2d

name of the center: T

coordinates of the center: [v1*t-2*(1-1/4*b^2)^(1/2), b]

radius of the circle: 1

equation of the circle: x^2-1+y^2+(-2*v1*t+4*(1-1/4*b^2)^(1/2))*x-2*b*y+(v1*t-2*(1-1/4*b^2)^(1/2))^2+b^2 = 0

> Kugel 1 nach dem Stoß

> circle(k1sm,[point(TSM,[V1S[1]*t+coordinates(P)[1],V1S[2]*t+coordinates(P)[2]]),1]):

Kugel 2 nach dem Stoß

>

> circle(k2sm,[point(T2SM,[V2S[1]*t,V2S[2]*t]),1]):

>

Eingabe der Parameter (verschiedene Geschwindigkeiten bewirken einen Zoom, räumlich und zeitlich - besonders eindrucksvoll in der Animation...):

> v1:=10:
m1:=100:m2:=1:
b:=1:

> plots[display]([seq(draw([k1t,k2],color=[blue,red],axes=normal,printtext=false,filled=true),t=seq(0.1*i,i=-5..0))],[seq(draw([k1sm,k2sm],color=[blue,red],axes=normal,printtext=false,filled=true),t=seq(0.1*j,j=1..10))],scaling=constrained);

[Maple Plot]

>

Neue Parameter

>

Welche Vermutungen über das Verhalten der Kugeln nach dem Stoß ergeben sich beim 'systematischen Spiel' mit den Parametern?

>

Analysis

Über dem Spiel mit den Parametern haben wir die Prüfungssituation vergessen. Dafür sind uns Hilfsmittel aus der Analysis und Algebra eingefallen, mit denen wir z.B. die Beträge der Geschwindigkeiten nach dem Stoß untersuchen können.

>

Zunächst ein paar Kontrollausgaben:

> m1:='m1':m2:='m2':b:='b':v1:='v1':

> vt;vn;

>

[Maple Math]

[Maple Math]

> print(V1S);

[Maple Math]

> print(V2S);

[Maple Math]

>

>

Nun ein paar Festlegungen.

Betrag der Geschwindigkeit der ankommenden Kugel 1 nach dem Stoß:

> v1s:=sqrt(V1S[1]^2+V1S[2]^2);

[Maple Math]
[Maple Math]

>

Wir führen das Massenverhältnis x ein und normieren unwichtige Grössen auf 1:

> v1:=1: m2:=x*m1: m1:=1:

>

> v1s;

[Maple Math]

>

Wie verhält sich also der Betrag der Geschwindigkeit der Kugel 1 nach dem Stoß in Abhängigkeit vom Stoßparameter und Massenverhältnis?

> plot3d(v1s,x=0..10,b=0..2,axes=framed);

[Maple Plot]

>

Die Betrachtung des Plots von verschiedenen Seiten zeigt uns ein Minimum. Können wir es analytisch in den Griff bekommen?

> diff(v1s,x);

[Maple Math]
[Maple Math]
[Maple Math]

>

In Release 4 ist % durch " zu ersetzen

> simplify(%);

[Maple Math]

> solve(%,x);

[Maple Math]

>

Unabhängig vom Stoßparameter wird die ankommende Kugel also am stärksten gebremst, wenn die gestoßene Kugel die gleiche Masse hat.

>

Wie ändert sich die Geschwindigkeit von Kugel 1 nach dem Stoß mit dem Stoßparameter?

> diff(v1s,b);

[Maple Math]
[Maple Math]
[Maple Math]

> simplify(%);

[Maple Math]

> solve(%,b);

[Maple Math]

>

Unabhängig vom Massenverhältnis wird die ankommende Kugel also am stärksten beim zentralen Stoß abgebremst.

>

Was können wir den folgenden Grenzwerten entnehmen?

> limit(v1s,x=infinity);

[Maple Math]

> limit(v1s,x=0);

[Maple Math]

> limit(v1s,b=2);

[Maple Math]

> limit(v1s,b=0);

[Maple Math]

>

Und wie verhält sich die Geschwindigkeit der Kugel 2 nach dem Stoß?

> v2s:=sqrt(dotprod(V2S,V2S,'orthogonal'));

[Maple Math]

>

> plot3d(v2s,x=0..10,b=0..2,axes=framed);

[Maple Plot]

>

Also Extrema nur an den Rändern...

>

Wir sollten die Geschwindigkeiten der Kugeln noch gemeinsam betrachten:

> plot3d({v1s,v2s},x=0..10,b=0..2,axes=framed);

[Maple Plot]

>

>

Vielleicht interessiert sich ein Thermodynamiker (es muß ja nicht gleich Maxwells Dämon sein) dafür, unter welchen Bedingungen sich beide Kugeln (Gasmoleküle) nach dem Stoß gleich schnell bewegen:

> solve(v1s=v2s,x);

[Maple Math]

> solve(v1s=v2s,b);

[Maple Math]

>

Eine erstaunlich einfache Beziehung! Wir sollten sie uns zeigen lassen:

> schnitt:=plots[spacecurve]([-b^2+3,b,subs(x=-b^2+3,v1s)],b=0..2,thickness=2,color=black,axes=framed):schnitt;

[Maple Plot]

>

> plots[display](schnitt,plot3d({v1s,v2s},x=0..10,b=0..2,axes=framed));

[Maple Plot]

>

Läßt sich der Teil der Kurve für x < 0 interpretieren?

>

>

Aber ein richtiger Thermodynamiker interessiert sich mehr für Energien als für Geschwindigkeiten:

> E1s:=m1/2*v1s^2;

[Maple Math]

> E2s:=m2/2*v2s^2;

[Maple Math]

>

> plot3d({E1s,E2s},x=0..4,b=0..2,axes=framed);

[Maple Plot]

>

Das sieht ja so symmetrisch aus... von verschiedenen Seiten betrachtet...

Was das wohl zu bedeuten hat?

>

> solve(E1s=E2s,x);

[Maple Math]

>

> solve(E1s=E2s,b);

[Maple Math]

>

Und so könnten wir weitermachen

> Eschnitt1:=plots[spacecurve]([-b^2+3+sqrt(b^4-6*b^2+8),b,subs(x=-b^2+3+sqrt(b^4-6*b^2+8),E1s)],b=0..2,thickness=2,color=black,axes=framed):Eschnitt1;

.....

>

Aber das würde wohl den Rahmen einer Klausur sprengen...

>

>

>

komma@oe.uni-tuebingen.de